/* --------------------------
Entry: 0005
WWW: http://
Title: anf_02_reduced_01
Author: Pete Capasso
---------------------------*/

#version 3.5;
// anf_02_reduced_01.pov by pete capasso
// povray@bestweb.net
// this is a reduced version of anf_02: all of the tech greebles and
// grids and overlays and stuff have been removed
#declare main_hue = <0.5, 1, 0>;
#macro camera_transforms()
  translate <0, 0.05, -3.5> * 2
#end
#macro overlay_transforms()
  translate <0, 0, 1>
  camera_transforms()
#end
#macro add_alpha(rgb_in, the_alpha)
  #local fvec = <0, 0, 0> + rgb_in; // force to be a 3-vector
  <fvec.x, fvec.y, fvec.z, the_alpha>
#end
global_settings {
  assumed_gamma 2.2 // make this the same as your display_gamma setting
  noise_generator 1
  max_trace_level 12
}
camera {
  location <0, 0, 0>
  direction <0, 0, 1.0>
  up <0, 1, 0>
  right <(image_width / image_height), 0, 0>
  camera_transforms()
}
plane { // wall, back behind everything
  <0, 0, -1>, -1000
  no_shadow
  pigment {
    bozo
    warp { turbulence 2.3 }
    translate <-4.1, 5.3, 7.5>
    rotate <16, 33, 9>
    scale <1000, 1, 1>
    scale 50
    color_map {
      [ 0.0 color rgb main_hue * 0.02 ]
      [ 1.0 color rgb main_hue * 0.20 ]
    }
  }
  finish { ambient 1 diffuse 0 }
  camera_transforms()
}
union {
  julia_fractal { // outer
    <0.655, 0.898, 0.91, -0.545>
    quaternion
    sqr
    max_iteration 7
    precision 700
    scale 2
    pigment { color rgb <1, 0.9, 0> }
    finish {
      ambient 0 diffuse 1.0
      specular 1.3 brilliance 3.0
    }
  }
  julia_fractal { // inner
    <-0.053, 0.664, 0.433, -0.262>
    quaternion
    cube
    max_iteration 11
    precision 600
    // slice <0.290252, 0.070119, -0.302303, -0.642374>, 0.0
    scale 1.99
    pigment { color rgb <0, 0.9, 0> }
    finish { ambient 0 diffuse 1.0 specular 1.3 brilliance 3.0 }
  }
  rotate y*30
  rotate z*90
  scale <-1, 1, 1>
  scale 2
}
light_source {
  <200, 300, -600>
  color red 1 green 1 blue 1
}
/* actual end of this file */