#include "colors.inc"

/*
   Test cylinder and top/bottom pieces
*/

camera {
   spherical
   location <0,0,0>
   up y
   right image_width*x/image_height
   angle 360
   sky <0,1,0>
   look_at <1,0,0>
}

global_settings { ambient_light rgb <1,1,1> }
background { color rgb <0,0,0> }

light_source {
  <0,0,0>
  color rgb <1,1,1>
}

#declare texture0 = texture {
   pigment { image_map { jpeg "temple_c.jpg" map_type 2 once interpolate 2 } }
   finish { ambient 1 diffuse 0 specular 0 }
}
#declare texture1 = texture {
   pigment { image_map { jpeg "temple_1.jpg" map_type 0 once interpolate 2 } }
   finish { ambient 1 diffuse 0 specular 0 }
}
#declare texture2 = texture {
   pigment { image_map { jpeg "temple_2.jpg" map_type 0 once interpolate 2 } }
   finish { ambient 1 diffuse 0 specular 0 }
}

#declare vfov = 120;
#declare dz = tan(0.5*radians(vfov));

difference {
   cylinder { <0,-dz,0>,<0,dz,0>,1.01 }
   cylinder { <0,-2*dz,0>,<0,2*dz,0>,1 }
   texture { 
      texture0 
      translate <0,-0.5,0>
      scale <-1,2*dz,1>
   }
}

plane {
   <0,0,1>, 0
   texture { texture1 }
   translate <-0.5,-0.5,0>
   scale <2,2,1>
   rotate <90,0,0>
   rotate <0,90,0>
   translate <0,dz,0>
}

plane {
   <0,0,1>, 0
   texture { texture2 }
   translate <-0.5,-0.5,0>
   scale <2,2,1>
   rotate <90,0,0>
   rotate <0,90,0>
   translate <0,-dz,0>
}